【X68000(Z)アセンブラ講座 第025回 V-DISP割り込み】


　
こんにちは!!

今回はモニターの画面更新のタイミング(60fps)で発生するV-DISP割り込みを使って
60fpsで画面を更新するプログラムを解説します。
(実機は55fpsだった気がしますが、それぞれ調べてみて下さい。)


破線の内側を'V_DISP.s'と言うファイル名で保存して下さい。
------------------------------------------------------------------------------------------------
　 	********************************************************************************
	*
	*	アプリ名 : V_DISP.x
	*
	*	V-DISP割り込み
	*
	*	Ver1.00
	*
	********************************************************************************



include		A:\XC\INCLUDE\DOSCALL.MAC	* OSコール用マクロの読み込み
include		A:\XC\INCLUDE\IOCSCALL.MAC	* IOCS(BIOS)コール用マクロの読み込み



*	システム領域のアドレス
cg_palette	equ	$E82000		* CG用パレットデータの先頭アドレス
cg_buffer	equ	$C00000		* CG-VRAMの先頭アドレス
cg_scroll_x	equ	$E80018		* CGスクロール X
cg_scroll_y	equ	$E8001a		* CGスクロール Y
sp_palette	equ	$E82200		* スプライト用パレットデータの先頭アドレス
sp_pattern	equ	$EB8000		* スプライトパターンデータの先頭アドレス
sp_controll	equ	$EB0000		* スプライトスクロールレジスターの先頭アドレス
vdisp		equ	$E88001		* %00010000でV-DISPチェックする
vec_vdisp	equ	$000118		* V-DISP割り込み
vec_hsync	equ	$00013C		* 
pad1		equ	$E9A001		* ゲームパッド１
pad2		equ	$E9A003		* ゲームパッド２



.cpu	68000				* CPUのタイプ


.data		* '.data'以降のデータはデータセクションに配置される

vec118:	dc.l	0	* V-Sync
vec13C:	dc.l	0	* H-Sync


mx:	dc.w	128			* 自キャラX座標
my:	dc.w	128			* 自キャラY座標


sp00:
	dc.b	$ff,$ff,$ff,$ff
	dc.b	$ff,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$f1,$11,$11,$11
	dc.b	$ff,$ff,$ff,$ff
	dc.b	$ff,$ff,$ff,$ff
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$11,$11,$11,$1f
	dc.b	$ff,$ff,$ff,$ff

sppal01: *	 GGGGG RRRRR BBBBB A
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_11111_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%00000_00000_00000_0
	dc.w	%11111_11111_11111_0


.bss					* '.bss'以降データバッファ




.text		* '.text'以降のプログラムはテキストセクションに配置される

start:				* スタートアドレス
	* カーソルをオフにする
	moveq.l	#_OS_CUROF,d0
	trap	#15

	* ランダム関数の初期化
	move.l	#23456,d0	* d0.lにランダムのシードを代入する
	dc.w	$FE0D		* ランダムのシードを設定する

 	* ユーザーモードからスーパーバイザーモードに移行する
	moveq.l	#_B_SUPER,d0	* d0にIOCS(BIOS)機能番号を代入
	move.l	#0,d1		* 数値0をd1に代入
	movea.l	d1,a1		* d1をa1にコピー
	trap	#15		* IOCSコール実行

	* 画面モードの設定
	moveq.l	#_CRTMOD,d0	* 画面モードの設定
	move.w	#10,d1		* 画面モードの番号 : 16 = 768x512x4bit / 10 = 256x256x8bit
	trap	#15

	* 画面をクリアして表示をオンにする
	moveq.l	#_G_CLR_ON,d0	* 画面をクリアして表示をオンにする
	trap	#15

	* スプライト表示をオンにする
	moveq.l	#_SP_ON,d0
	trap	#15

	bsr	set_palette	* スプライトパレット設定ルーチンの呼び出し
	bsr	set_sprite	* スプライトパターンデータの定義ルーチンの呼び出し






	* V-DISP割り込みの設定
	move.l	vec_vdisp,vec118	* 割り込みのアドレスをバックアップ
	lea	int_vdisp,a0		* 割り込みとしてint_vdispルーチンのアドレスを
	move.l	a0,vec_vdisp		* 割り込みベクトルに登録する。
	or.b	#%01000000,$E88015	* V-DISP割り込みのマスクの設定
	or.b	#%01000000,$E88009	* V-DISP割り込みの許可の設定
	and.b	#%11101111,$E88003	* 垂直帰線期間で割り込み発生


loop:				* メインループ開始
*	V-DISPビットを監視してメインループを60fpsで動作させるタイミングを取る
	movea.l	#vdisp,a0
vdisp_1:
	move.b	(a0),d0
	and.b	#$10,d0
	tst.b	d0
	beq	vdisp_1
vdisp_2:
	move.b	(a0),d0
	and.b	#$10,d0
	tst.b	d0
	bne	vdisp_2



*	[ESC]キーが押されたら終了処理'end:'にジャンプする
	moveq.l	#_BITSNS,d0
	moveq.l	#0,d1
	trap	#15
	and.b	#%00000010,d0
	tst.b	d0
	bne	end

	bra	loop		* メインループの最初にジャンプする


end:

	* V-DISP割り込みの終了処理
	and.b	#%10111111,$E88015
	and.b	#%10111111,$E88009
	move.l	vec118,vec_vdisp


*	moveq.l	#_CRTMOD,d0
*	move.w	#16,d1
*	trap	#15

	* マウスカーソルをオンにする
	moveq.l	#_OS_CURON,d0
	trap	#15

	* スーパーバイザーモードからユーザーモードに戻る
	moveq.l	#_B_SUPER,d0
	move.l	SP,a1
	trap	#15


	* アプリ終了
	dc.w	_EXIT		* OSコール実行 : _EXIT = プログラムの終了



* 割り込みプログラム
int_vdisp:			* V_DISP割り込み(1/60秒毎に呼び出される)

	movem.l	d0-d4,-(sp)

	* スプライトX座標に1を足す
	addq.w	#1,mx		* スプライトX座標に１を足す(右に移動する)
	cmp.w	#256+16,mx	* 画面右端はみ出しチェック
	blt	int_vdisp_1	* はみ出していない場合はint_vdisp_1にジャンプする
	move.w	#0,mx		* スプライトのX座標を０にする
int_vdisp_1:
*	スプライトの表示
	moveq.l	#0,d0		* 表示するスプライト番号(0 - 127)
	move.w	mx,d1		* スプライトX座標(0 - 1023)
	move.w	my,d2		* スプライトY座標(0 - 1023)
	move.w	#$0101,d3	* スプライト情報
	move.w	#3,d4		* プライオリティ
	bsr	put_sprite	* スプライト表示ルーチンの呼び出し

int_vdisp_e:
	movem.l	(sp)+,d0-d4

	rte			* 割り込みルーチンの終了




*	RGBQUAD { Blue8, Green8, Red8, Reserved8 } = %RRRRRRRR_GGGGGGGG_BBBBBBBB_AAAAAAAA
*	palette { Green5, Red5, Blue5, Alpha1 } =    %GGGGG_RRRRR_BBBBB_A

*	Set Sprite Palette
set_palette:
f	movea.l	#sp_palette,a0 * スプライト用パレットレジスターアドレス
	adda.l	#32,a0
	lea	sppal01,a1	* パレットデータバッファアドレス
	moveq.l	#0,d7
set_palette_1:
	move.w	(a1)+,(a0)+
	addq.w	#1,d7			* 色番号を次の番号に更新する
	cmp.w	#16,d7			* 現在の色番号と16を比較する
	blt	set_palette_1		* 現在の色番号が16未満ならアドレスset_palette_1に飛ぶ

	rts				* 呼出元に戻る



*	スプライトパターンの定義
set_sprite:
	lea	sp00,a0
	movea.l	#sp_pattern,a1
	adda.l	#128,a1
	moveq.l	#0,d7
set_sprite_1:
	move.l	(a0)+,(a1)+
	addq.w	#1,d7
	cmp.w	#32,d7
	blt	set_sprite_1

	rts


put_sprite:
* d0.w = 表示するスプライトの番号(0 - 127)
* d1.w = %000000XXXXXXXXXX	* X座標
* d2.w = %000000YYYYYYYYYY	* Y座標
* d3.w = %VH00CCCCSSSSSSSS	* スプライト情報
* d4.w = %00000000000000PP	* プライオリティ設定

	movem.l	d0/a0,-(sp)

	movea.l	#sp_controll,a0
	ext.l	d0
	lsl.l	#3,d0		* d0の値を８倍にする
	adda.l	d0,a0

	move.w	d1,(a0)+
	move.w	d2,(a0)+
	move.w	d3,(a0)+
	move.w	d4,(a0)+

	movem.l	(sp)+,d0/a0
	rts




* End Of File
------------------------------------------------------------------------------------------------

コマンドプロンプトから、

A>as V_DISP.s [Enter]
A>lk V_DISP.o [Enter]
A>V_DISP.x [Enter]

のように入力すると
スプライトが移動します。
ソースコード中の画像の座標を書き換えて
表示する位置を変える事もできます。
ESCキーで終了します。


[ プログラムの解説 ]

・割り込みとは

PCが通常動作中に特定の条件や異変が起きた時などに
通常動作中のプログラムを一時的に止めて
用意されていた異変などに対応したプログラムを優先的に実行すること。
実行し終えたらすぐ通常動作に戻る。

・V-DISP割り込みとは

PCなどのモニターは１秒間に60コマの速度(更に速いモニターもあります)で映像を更新していて
１コマの更新が終わるたびにプログラマーが用意した任意の処理をするプログラムを実行する。

今回の割り込みプログラムは毎フレームの間隔でスプライトの座標に１を足して
移動というアニメーションを実現しています。

今回の講座も簡単に理解できたと思います。


それではまた!!